Core Function GUIWndProc

DLLStructCreateDef("WindowPos", 
				@"
				ptr hwnd;
				ptr hwndInsertAfter;
				int x;
				int y;
				int cx;
				int cy;
				uint flags
				");
 
// Create the MDI GUI
$GUI = GUICreate("MDIWindow", "GUI", 800, 600);
// Show the MDI GUI
GUILoad( $GUI );
 
// Create the Design Window
$Window = GUICreate("Window", "GUI", 640, 482, 0, 0);
GUIMDIParent($Window, $GUI);
// Show the Design Window
GUILoad( $Window );
// Add a MsgFilter to Design Window
GUIWndProc($Window, 'WndProc($HWND, $MSG, $WPARAM, $LPARAM);');
 
// Keep the GUI running as long as long as the window is open
While ( GUIStatus( $GUI ) ) DoEvents( );
 
// When you create a WndProc 4 variables are automatically created for you
// $HWND
// $MSG
// $WPARAM
// $LPARAM
// All them names should be familiar to you
Function WndProc($HWND, $MSG, $WPARAM, $LPARAM)
{
	// Uncomment to show all messages
	//println("HWND: " . $HWND . " | MSG: " . $MSG . " | WParam: " . $WParam . " | LParam: " . $LParam);
	// Get a message when user tries to move the Design window
	if ($MSG == 0x0046) # WM_WINDOWPOSCHANGING
	{
		// Uncomment to see how to read from the memory pointer
		//println("X: " . PTRRead( $LParam, "i", 8 ));
		//println("Y: " . PTRRead( $LParam, "i", 12 ));
 
		// Heres the best way to read the pointer by converting it into a Structure
		$Struct = PTRToDLLStruct("WindowPos", $LParam);		
		println("X: " . DLLStructGetData($Struct, "x"));
		println("Y: " . DLLStructGetData($Struct, "y"));
 
		// Set the new coordinates for the Design window to 0, 0 this will prevent it from being moved
		DLLStructSetData($Struct, "x", 0);
		DLLStructSetData($Struct, "y", 0);
	}
	return 0; // If you return HIGHER than 0 the WindProc callback will be removed
}